ПРИЛОЖЕНИЕ 2. КОМПЬЮТЕРНАЯ ПРОГРАММА ИССЛЕДОВАНИЯ РАСПРЕДЕЛЕНИЯ СЛУЧАЙНЫХ ВЕЛИЧИН

COLOR 7,0:CLS:LOCATE 2,60,0:COLOR 25,5,15:PRINT"ВКЛЮЧИТЕ ПРИНТЕР"

2 COLOR 7,7,15:LOCATE 4:COLOR 0,7,15

3 PRINT TAB(27)" ЗАДАЧА R N D";:PRINT SPC(37):PRINT TAB(26)" ";

4 COLOR 15,0,15:PRINT"КАФЕРА";:COLOR 23,5,15:PRINT"*БНТУ*";

5 COLOR 15,0,15:PRINT" ОАПДД ";:COLOR 7,7,15:PRINT SPC(35):COLOR 1,14

6 PRINT TAB(20)"ИССЛЕДОВАНИЕ РАСПРЕДЕЛЕНИЯ СЛУЧАЙНЫХ";

7 PRINT TAB(80)" ";:PRINT TAB(33)"ВЕЛИЧИН";

8 PRINT TAB(80)" ":DEFINT I-N

19 PRINT:COLOR 7,0,7

35 COLOR 1,6,14

IMAX=3

LOCATE 5,33,0:COLOR 7,5,15:PRINT"*БНТУ*";

I=1

LOCATE 8,30,0:COLOR 25,4:PRINT"ВВЕДИТЕ РЕЖИМ"

50 J=1

IF J=I THEN COLOR 4,11 ELSE COLOR 1,11

LOCATE 9,25,0:PRINT "╔════════════════════════╗"

LOCATE 10,25,0:PRINT"║ Д И С К Р Е Т Н О Е ║"

LOCATE 11,25,0:PRINT"║ *РАСПРЕДЕЛЕНИЕ* ║"

LOCATE 12,25,0:PRINT"╚════════════════════════╝"

J=2

IF J=I THEN COLOR 4,11 ELSE COLOR 1,11

LOCATE 13,25,0:PRINT"╔════════════════════════╗"

LOCATE 14,25,0:PRINT"║ Н Е П Р Е Р Ы В Н О Е ║"

LOCATE 15,25,0:PRINT"║ *РАСПРЕДЕЛЕНИЕ* ║"

LOCATE 16,25,0:PRINT"╚════════════════════════╝"

J=3

IF J=I THEN COLOR 4,11 ELSE COLOR 1,11

LOCATE 21,25,0:PRINT"╔════════════════════════╗"

LOCATE 22,25,0:PRINT"║ ** ВЫХОД ** ║"

LOCATE 23,25,0:PRINT"╚════════════════════════╝"

95 AM$=INKEY$

IF LEN(AM$)=0 THEN 95

AM1$=RIGHT$(AM$,1)

IF ASC(AM1$)=80 THEN I=I+1:GOTO 100

IF ASC(AM1$)=72 THEN I=I-1:GOTO 100

IF ASC(AM1$)=13 GOTO 110

GOTO 95

100 IF I>IMAX THEN I=1

IF I<1 THEN I=IMAX

GOTO 50

110 COLOR 1,11

IF I=1 THEN SHELL "RNDD.EXE":GOTO 1

IF I=2 THEN SHELL"RNDN.EXE":GOTO 1

120 END

REM МОДУЛЬ ИССЛЕДОВАНИЯ НЕПРЕРЫВНЫХ СЛУЧАЙНЫХ ВЕЛИЧИН

2 COLOR 7,7,15:CLS:LOCATE 10:PRINT:COLOR 0,7,15

3 PRINT TAB(27)"З А Д А Ч А R N D N":PRINT TAB(26)" ";

4 COLOR 23,0,15:PRINT"КАФЕДРА";:COLOR 23,5,15:PRINT" *БНТУ*";

5 COLOR 15,0,15:PRINT" О А П Д Д":PRINT:COLOR 1,14

6 PRINT TAB(21)"ИССЛЕДОВАНИЕ РАСПРЕДЕЛЕНИЯ НЕПРЕРЫВНОЙ";

7 PRINT TAB(80)" ";:PRINT TAB(27)"СЛУЧАЙНОЙ ВЕЛИЧИНЫ";

8 PRINT TAB(80)" ":DEFINT I-N

9 COLOR 7,10,15

12 PRINT:COLOR 7,0,7

20 DIM A(1500),AA(1500)

22 OPEN"O",#3,"RNDNR.REZ"

25 COLOR 0,7

30 PRINT "ВВЕДЕНЫ ЛИ ИСХОДНЫЕ ДАННЫЕ"

35 COLOR 15,0

40 PRINT "ДА- 1, НЕТ- 0":INPUT IR1

50 IF IR1=0 THEN 200

55 INPUT"СПЕЦИФИКАЦИЯ ФАЙЛА С ИСХОДНЫМИ ДАННЫМИ";IMF$

60 OPEN"I",#1,IMF$

65 INPUT #1,SI$

70 INPUT #1,NO

80 FOR I=1 TO NO:INPUT #1,A(I):NEXT I

90 CLOSE #1

100 CLS:PRINT" № П/П ЧИСЛО"

105 FOR I=1 TO NO:PRINT TAB(((I-1) MOD 4)*16+1)"│"I;USING"#####.####";A(I);

107 IF I MOD 4=0 THEN PRINT

110 NEXT I

115 COLOR 23,0

120 PRINT "ТРЕБУЕТСЯ ЛИ КОРРЕКТИРОВАТЬ ИСХОДНЫЕ ЗНАЧЕНИЯ"

130 PRINT "СЛУЧАЙНОЙ ВЕЛИЧИНЫ. ДА- 1,НЕТ- 0":INPUT IR0

135 COLOR 15,0

140 IF IR1=0 AND IR0=0 THEN 230

150 IF IR0=0 THEN 270

160 PRINT "ПОРЯДКОВЫЙ НОМЕР(СЧИТАЯ С ЕДИНИЦЫ) ЧИСЛА,ПОДЛЕЖАЩЕГО"

170 PRINT "ИЗМЕНЕНИЮ":INPUT IS

175 PRINT "ЗАМЕНЯТЬ ЧИСЛО "A(IS)"?":INPUT IRR:IF IRR=0 THEN 120

180 IF IS<1 OR IS>NO THEN PRINT "ВЫ ДОПУСТИЛИ ОШИБКУ":GOTO 160

190 PRINT "НОВОЕ ЧИСЛО":INPUT A(IS):IR1=0:GOTO 120

200 CLS:PRINT "ВВЕДИТЕ ИСХОДНЫЕ ДАННЫЕ":INPUT "НАИМЕНОВАНИЕ ДАННЫХ";SI$

205 INPUT "РАЗМЕР ВЫБОРКИ";NO

210 PRINT "ПОСЛЕДОВАТЕЛЬНО ЧИСЛА ВЫБОРКИ"

220 FOR I=1 TO NO:PRINT I"-E":INPUT A(I):NEXT I:GOTO 100

230 IF IR1=1 THEN 232

231 INPUT"ЗАДАЙТЕ ИМЯ ФАЙЛА ДЛЯ ИСХОДНЫХ ДАННЫХ";IMF$

232 OPEN "O",#1,IMF$

235 WRITE #1,SI$

240 WRITE #1,NO

250 FOR I=1 TO NO:WRITE #1,A(I):NEXT I

260 CLOSE #1

270 DIM UB(3),FR(50),ST(50),X(50),P(50),PT(50),P1(50),IN(7)

280 DIM P9(50),XX(50),A1(500),PM(7),PS(7),Z$(7),Z1$(7),Z2$(7)

285 PRINT #3, TAB(10)"ИССЛЕДОВАНИЕ РАСПРЕДЕЛЕНИЯ СЛУЧАЙНОЙ";

286 PRINT #3," ВЕЛИЧИНЫ":PRINT #3, TAB(10)"("SI$")"

290 Z$(1)="НОРМАЛЬНОЕ":Z1$(1)="M":Z2$(1)="SIGMA"

300 Z$(2)="ЛОГНОРМАЛЬНОЕ":Z1$(2)="LNU":Z2$(2)="SIGMA^2"

310 Z$(3)="РЕЛЕЯ":Z1$(3)="SIGMA":Z2$(3)=""

320 Z$(4)="ЭКСПОНЕНЦИАЛЬНОЕ":Z1$(4)="LAMBDA":Z2$(4)=""

330 Z$(5)="ЭРЛАНГА":Z1$(5)="LAMBDA":Z2$(5)="K"

340 Z$(6)="ВЕЙБУЛЛА":Z1$(6)="B":Z2$(6)="LAMBDA"

342 Z$(7)="РАВНОМЕРНОЕ":Z1$(7)="A":Z2$(7)="B"

345 Z7$=" РАСПРЕДЕЛЕНИЕ НЕ ПОДХОДИТ"

346 Z8$=" РАСПРЕДЕЛЕНИЕ "

347 F1$="-#.##^^^^":F2$="-#.##^^^^"

350 PRINT #3,:PRINT #3, TAB(5)"ИСХОДНЫЕ ДАННЫЕ"

355 FOR I=1 TO NO:AA(I)=A(I):NEXT I:NF=NO:GOSUB 360:GOTO 410

360 N4=0

370 FOR I=1 TO NF

375 N4=N4+1:IF N4>8 THEN N4=1:PRINT #3,

380 PRINT #3,USING F1$;AA(I);

390 NEXT I

405 PRINT #3,:PRINT #3,:RETURN

410 ID=1

420 ID=2*ID

430 IF ID<=NO THEN 420

440 ID=INT((ID-1)/2!)

450 IF ID=0 THEN 580

460 FOR I1=1 TO NO-ID:J=I1

470 L=J+ID

480 IF A(L)>=A(J) THEN 510

490 XR=A(J):A(J)=A(L):A(L)=XR:J=J-ID

500 IF J>0 THEN 470

510 NEXT I1

520 GOTO 440

580 PRINT #3, " НАИМЕНЬШЕЕ ВЫБОРОЧНОЕ ЗНАЧЕНИЕ =";

585 PRINT #3, USING F1$;A(1)

590 PRINT #3, " НАИБОЛЬШЕЕ ВЫБОРОЧНОЕ ЗНАЧЕНИЕ =";

592 PRINT #3, USING F1$;A(NO)

595 A(1)=A(1)+1.E-36:A(NO)=A(NO)+1.E-36

596 UB(1)=A(1):UB(3)=A(NO)

597 FOR I=2 TO NO:IF A(I)=0 THEN A(I)=1.E-36:NEXT I

600 N8=CINT(1.44*LOG(NO)):N9=0

610 IF N8<4 THEN N8=4

620 PRINT " *РЕКОМЕНДУЕМОЕ ЧИСЛО ИНТЕРВАЛОВ "N8

630 GOTO 700

640 IF IR9=1 THEN 1090

650 PRINT"ТРЕБУЕТСЯ ПРОДОЛЖИТЬ РАСЧЕТЫ С ЭТИМИ ДАННЫМИ";

651 INPUT"(ДА- 1,НЕТ- 0)";N5

660 IF N5=0 THEN 3070

670 PRINT"*ТРЕБУЕТСЯ ИЗМЕНЯТЬ ЧИСЛО ИНТЕРВАЛОВ ИЛИ"

680 INPUT "*СМЕЩЕНИЕ(ДА- 1,НЕТ- 0)";N7

690 IF N7=0 THEN 1160

700 INPUT " * ВВЕДИТЕ ЧИСЛО ИНТЕРВАЛОВ";N

710 UB(2)=N+2

720 INPUT " *ВВЕДИТЕ ЗНАЧЕНИЕ СМЕЩЕНИЯ";XM

730 GOSUB 2070

740 IF N9<>0 THEN 800

750 N9=1:V=ST(3)/ST(2)

760 PRINT #3, " МАТЕМАТИЧЕСКОЕ ОЖИДАНИЕ =";

765 PRINT #3, USING F1$;ST(2)

770 PRINT #3, " СРЕДНЕКВАДРАТИЧЕСКОЕ ОТКЛОНЕНИЕ =";

775 PRINT #3, USING F1$;ST(3)

780 PRINT #3, " КОЭФФИЦИЕНТ ВАРИАЦИИ =";

785 PRINT #3, USING F1$;V

790 PRINT #3, " -------*****-------- "

800 PRINT #3, " ЧИСЛО ИНТЕРВАЛОВ ="N

810 PRINT #3, " ЗНАЧЕНИЕ СМЕЩЕНИЯ =";

815 PRINT #3, USING F1$;XM

820 PT(1)=PT(1)*100

840 FOR I=1 TO N

850 P9(I+1)=PT(I+1):PT(I+1)=P9(I+1)*100:NEXT I

860 R=(UB(3)-UB(1))/(UB(2)-2)

870 FOR I=1 TO N:XI=I:X(I)=UB(1)+R*XI-R/2:NEXT I

880 PRINT #3,:PRINT #3, " СЕРЕДИНЫ ИНТЕРВАЛОВ"

890 FOR I=1 TO N:AA(I)=X(I):NEXT I:NF=N:GOSUB 360

920 PRINT #3, " ВЕКТОР ЭМПИРИЧЕСКИХ ЧАСТОТ "

930 FOR I=1 TO N:AA(I)=FR(I+1):NEXT I:NF=N:GOSUB 360

950 PRINT #3, " ВЕКТОР ЭМПИРИЧЕСКИХ ЧАСТОСТЕЙ"

960 FOR I=1 TO N:AA(I)=P9(I+1):NEXT I:NF=N:GOSUB 360

980 PRINT #3, TAB(15)"** X **":PRINT #3,

990 PRINT "ТРЕБУЕТСЯ ЛИ ПОИСК ЗАКОНА РАСПРЕДЕЛЕНИЯ ПО МАКСИМУМУ"

1000 INPUT "ЗНАЧЕНИЯ КРИТЕРИЯ РОМАНОВСКОГО(ДА- 1,НЕТ- 0)";IR9

1010 IF IR9=0 THEN 1160

1020 PRINT#3,"┌────────┬───────────┬────────┬────────┐"

1025 PRINT#3,"│ │ │ │ │"

1030 PRINT#3,"│РАСПРЕ- │ ПАРАМЕТРЫ │ЧИСЛО │ КРИТЕРИЙ │"

1040 PRINT#3,"│ДЕЛЕНИЕ │ │СТЕПЕНЕЙ │ РОМАНОВ- │"

1050 PRINT#3,"│ │ │СВОБОДЫ │ СКОГО │"

1060 PRINT#3,"└────────┴───────────┴────────┴────────┘"

1065 PRINT #3,

1070 MI=0:RM=1E+10

1080 MI=MI+1:ON MI GOTO 1290,1500,1590,1670,1750,1870,2061

1090 IF RK<RM THEN RM=RK:JM=MI

1100 PRINT #3, Z$(MI);TAB(18)Z1$(MI);"=";:PRINT #3, USING F1$;PM(MI);

1110 IF IN(MI)=1 THEN PRINT #3, " "Z2$(MI);"=";:PRINT #3, USING F1$;PS(MI);

1120 PRINT #3, TAB(50)NU;:PRINT #3, TAB(58)USING F1$;RK

1130 IF MI<7 THEN 1080

1140 N3=JM:IR9=0

1150 PRINT #3,:PRINT #3,:PRINT #3, "НАИЛУЧШЕЕ ПО КРИТЕРИЮ РОМАНОВСКОГО - ";:GOTO 1250

1160 PRINT " * ВВЕДИТЕ НОМЕР РАСПРЕДЕЛЕНИЯ;"

1170 PRINT

1180 PRINT " 1 - "Z$(1)

1190 PRINT " 2 - "Z$(2)

1200 PRINT " 3 - "Z$(3)

1210 PRINT " 4 - "Z$(4)

1220 PRINT " 5 - "Z$(5)

1230 PRINT " 6 - "Z$(6)

1235 PRINT " 7 - "Z$(7)

1240 INPUT N3

1250 ON N3 GOTO 1260,1500,1590,1670,1750,1870,2061

1260 PRINT #3,:PRINT #3, TAB(10)Z$(1);Z8$

1270 PRINT #3,:PRINT #3, TAB(5)Z1$(1)"=";:PRINT #3, USING F1$;ST(2)

1280 PRINT #3, TAB(5)Z2$(1)"=";:PRINT #3, USING F1$;ST(3)

1290 IN(1)=1:PM(1)=ST(2):PS(1)=ST(3):XW=(XX(1)-ST(2))/ST(3):GOSUB 2820

1300 FOR I=1 TO N:FO=FW

1310 XW=(XX(I+1)-ST(2))/ST(3):GOSUB 2820:P(I)=FW-FO:NEXT I

1320 NU=N-3

1330 IF IR9=1 THEN 1480

1340 PRINT #3,:PRINT #3, " ВЕКТОР ТЕОРEТИЧЕСКИХ ЧАСТОСТЕЙ"

1350 FOR I=1 TO N:AA(I)=P(I):NEXT I:NF=N:GOSUB 360

1360 INPUT"ТРЕБУЮТСЯ ЛИ ГРАФИКИ РАСПРЕДЕЛЕНИЯ(ДА- 1,НЕТ- 0)";IR2

1370 IF IR2=0 THEN 1480

1380 PRINT #3,

1382 PRINT #3,"┌──────────────────────────────────────────────────>";

1385 PRINT #3,

1390 FOR I=1 TO N:P4=INT(P(I)*80)+1:P5=INT(PT(I+1)*80/100)+1

1400 IF P4<P5 THEN 1430

1410 IF P4>P5 THEN 1440

1411 PRINT #3,"│";

1412 FOR II=2 TO P4:PRINT #3,"░";:NEXT II:PRINT #3,

1413 PRINT #3,"│";

1414 FOR II=2 TO P4-1:PRINT #3,"░";:NEXT II

1420 PRINT #3,TAB(P4)"*"

1421 PRINT #3,"│";

1422 FOR II=2 TO P4:PRINT #3,"░";:NEXT II:PRINT #3,

1428 GOTO 1450

1430 PRINT #3,"│";

1431 FOR II=2 TO P5:PRINT #3,"░";:NEXT II:PRINT #3,

1432 IF P4<2 THEN 1434

1433 PRINT #3,"│";:FOR II=2 TO P4-1:PRINT #3,"░";:NEXT II

1434 PRINT #3,TAB(P4)"*";

1435 FOR II=P4+1 TO P5:PRINT #3,"░";:NEXT II

1437 PRINT #3,:PRINT #3,"│";

1438 FOR II=2 TO P5:PRINT #3,"░";:NEXT II:PRINT #3,

1439 GOTO 1450

1440 PRINT #3,"│";

1441 FOR II=2 TO P5:PRINT #3,"░";:NEXT II:PRINT #3,

1442 PRINT #3,"│";

1443 FOR II=2 TO P5:PRINT #3,"░";:NEXT II

1445 PRINT #3,TAB(P4)"*"

1446 PRINT #3,"│";

1447 FOR II=2 TO P5:PRINT #3,"░";:NEXT II:PRINT #3,

1450 NEXT I

1455 PRINT #3,"│"

1456 PRINT #3,"V"

1460 PRINT #3,"* -ТЕОРЕТИЧЕСКОЕ РАСПРЕДЕЛЕНИЕ"

1480 GOSUB 2250

1490 GOTO 640

1500 IN(2)=1:SI=LOG((ST(3)/(ST(2)-XM))^2+1):SL=SQR(SI)

1510 YL=LOG(ST(2)-XM)-SI/2:IF IR9=1 THEN 1550

1520 PRINT #3,:PRINT #3, TAB(10)Z$(2);Z8$

1530 PRINT #3,:PRINT #3, TAB(5)Z1$(2)"=";USING F1$;YL

1540 PRINT #3, TAB(5)Z2$(2)"=";:PRINT #3, USING F1$;SI

1550 PM(2)=YL:PS(2)=SI:XW=(LOG(XX(1)-XM)-YL)/SL:GOSUB 2820

1560 FOR I=1 TO N:FO=FW

1570 XW=(LOG(XX(I+1)-XM)-YL)/SL:GOSUB 2820:P(I)=FW-FO:NEXT I

1580 GOTO 1320

1590 IN(3)=0:SG=(ST(2)-XM)/1.2533:IF IR9=1 THEN 1620

1600 PRINT #3,:PRINT #3, TAB(10)Z8$;Z$(3)

1610 PRINT #3,:PRINT #3, TAB(5)Z1$(3)"=";:PRINT #3, USING F1$;SG

1620 PM(3)=SG:XW=(XX(1)-XM):GOSUB 2890

1630 FOR I=1 TO N:FO=FW

1640 XW=(XX(I+1)-XM):GOSUB 2890:P(I)=FW-FO:NEXT I

1650 NU=N-2

1660 GOTO 1330

1670 PL=1/(ST(2)-XM):IN(4)=0:IX=1:PM(4)=PL:IF IR9=1 THEN 1700

1680 PRINT #3,:PRINT #3, TAB(10) Z$(4);Z8$

1690 PRINT #3,:PRINT #3, TAB(5)Z1$(4)"=";:PRINT #3, USING F1$;PL

1700 XW=XX(1)-XM:GOSUB 2920

1710 FOR I=1 TO N:FO=FW

1720 XW=XX(I+1)-XM:GOSUB 2920:P(I)=FW-FO:NEXT I

1730 IF IX=2 THEN 1320

1740 NU=N-2:GOTO 1330

1750 IF((ST(2)-XM)/ST(3))^2<85 THEN 1755

1752 PRINT #3, Z$(5),Z7$:IF IR9=0 THEN 1160 ELSE 1080

1755 K=CINT(((ST(2)-XM)/ST(3))^2)

1760 IF K=0 THEN K=1

1770 EL=K/(ST(2)-XM):IN(5)=1:PM(5)=EL:PS(5)=K:IF IR9=1 THEN 1810

1780 PRINT #3,:PRINT #3, TAB(10)Z8$;Z$(5)

1790 PRINT #3,:PRINT #3, TAB(5)"LAMBDA=";:PRINT #3, USING F1$;EL

1800 PRINT #3, TAB(5)"K="K

1810 KK=K-1

1820 IF KK=O THEN IX=2:PL=EL:GOTO 1700

1830 XW=XX(1)-XM:GOSUB 2950

1840 FOR I=1 TO N:FO=FW

1850 XW=XX(I+1)-XM:GOSUB 2950:P(I)=FW-FO:NEXT I

1860 GOTO 1320

1870 B=.3:E=.001:H=.4:GOSUB 1930

1875 IF LOG(((ST(2)-XM)/G3)^B)<85 THEN 1880

1877 PRINT #3, Z$(6),Z7$:IF IR9=0 THEN 1160 ELSE 1140

1880 F1=F:B=B+H:GOSUB 1930

1890 IF ABS(F)<ABS(F1) THEN 1875

1900 H=-H/4:IF ABS(H)>E/4 THEN 1875

1910 B=B+H/4:Z=1/B+1:GOSUB 1970

1920 WL=((ST(2)-XM)/G3)^B

1926 IF IR9=0 THEN 2000 ELSE 2030

1930 Z=2/B+1:GOSUB 1970

1940 G1=G3:Z=1/B+1:GOSUB 1970

1950 G2=G3:F=G1/G2/G2-1-(ST(3)/(ST(2)-XM))^2

1960 RETURN

1970 G3=EXP(-Z)*Z^Z*(1+1/12/Z+1/(288*Z^2)-.7/(288*Z^3))

1980 G3=SQR(6.28319/Z)*G3

1990 RETURN

2000 PRINT #3,:PRINT #3, TAB(10)Z8$;Z$(6)

2010 PRINT #3,:PRINT #3, " B=";:PRINT #3, USING F1$;B

2020 PRINT #3, " LAMBDA=";:PRINT #3, USING F1$;WL

2030 IN(6)=1:PM(6)=B:PS(6)=WL:XW=XX(1)-XM:GOSUB 3010

2040 FOR I=1 TO N:FO=FW

2050 XW=XX(I+1)-XM:GOSUB 3010:P(I)=FW-FO:NEXT I

2060 GOTO 1320

2061 IN(7)=1:A=ST(2)-SQR(3)*(ST(3)):B=ST(2)+SQR(3)*(ST(3)):IF IR9=1 THEN 2065

2062 PRINT #3,:PRINT #3, TAB(10)Z$(7);Z8$

2063 PRINT #3,:PRINT #3, TAB(5)Z1$(7)"=";:PRINT #3, USING F1$;A

2064 PRINT #3, TAB(5)Z2$(7)"=";:PRINT #3, USING F1$;B

2065 PM(7)=A:PS(7)=B

2066 FOR I=1 TO N

2067 P(I)=1/N:NEXT I

2069 GOTO 1320

2070 N=UB(2)-2:R=(UB(3)-UB(1))/(UB(2)-2)

2080 FOR I=1 TO N:XI=I:XX(I)=UB(1)+R*(XI-1)

2090 FR(I+1)=0!:NEXT I

2100 XX(N+1)=UB(3)

2110 II=1:J=0:A(NO+1)=1E+30:VN=NO

2120 J=J+1

2130 I=II

2140 IF A(I)>XX(J+1) THEN 2170

2150 FR(J+1)=FR(J+1)+1

2160 I=I+1:GOTO 2140

2170 II=I:IF II>NO THEN 2180 ELSE 2120

2180 FOR I=1 TO N:PT(I+1)=FR(I+1)/VN:NEXT I

2190 SS=0:ST(2)=0:I=1

2200 IF A(I)<XX(1) OR A(I)>XX(N+1) THEN 2220

2210 ST(2)=ST(2)+A(I)/VN:SS=SS+A(I)^2/VN

2220 I=I+1:IF I<= NO THEN 2200

2230 ST(3)=SQR(VN/(VN-1)*(SS-ST(2)^2))

2240 RETURN

2250 FOR I=1 TO N:P1(I)=P(I):P9(I+1)=PT(I+1):NEXT I

2260 N1=N:N11=NU:NN=N-N11+1:SM=P1(1)*NO:SQ=0

2270 I=2:L1=0

2280 IF N-L1<=NN THEN 2330

2290 IF SM>=5 THEN 2330

2300 SM=SM+P1(I)*NO

2310 I=I+1:L1=L1+1

2320 GOTO 2280

2330 SM=P1(N)*NO

2340 I=0:L2=0

2350 IF N-L1-L2<=NN GOTO 2380

2360 IF SM>=5 GOTO 2380

2370 L2=L2+1:I=I+1:SM=SM+P1(N-I)*NO:GOTO 2350

2380 IF L1=0 THEN 2440

2390 FOR I=1 TO L1:PT(2)=PT(2)+PT(I+2)

2400 P(1)=P(1)+P(I+1):NEXT I

2410 N=N-L1

2420 FOR I=2 TO N:PT(I+1)=PT(I+1+L1)

2430 P(I)=P(I+L1):NEXT I

2440 IF L2=0 THEN 2480

2445 N=N-L2

2450 FOR I=1 TO L2:PT(N+1)=PT(N+1)+PT(N+1+I)

2460 P(N)=P(N)+P(N+I):NEXT I

2480 FOR I=1 TO N

2485 IF P(I)<1E-33 THEN SQ=9.999999E+33:GOTO 2495

2490 SQ=SQ+((P(I)-PT(I+1)/100)^2)/P(I)

2495 NEXT I

2500 SQ=SQ*NO

2510 NU=N11-L2-L1

2520 RK=(SQ-NU)/SQR(2*NU)

2530 IF IR9=1 THEN 2600

2540 PRINT #3,:PRINT #3, " ВЕКТОР ТЕОРЕТИЧЕСКИХ ЧАСТОСТЕЙ C"

2550 PRINT #3, " ОБЬЕДИНЕНИЕМ ИНТЕРВАЛОВ НА КОНЦАХ"

2560 FOR I=1 TO N:AA(I)=P(I):NEXT I:NF=N:GOSUB 360

2570 PRINT #3,:PRINT #3, " ЗНАЧЕНИЕ ХИ-КВАДРАТ =";:

2575 PRINT #3, USING F1$;SQ

2580 PRINT #3, " ЧИСЛО СТЕПЕНЕЙ СВОБОДЫ ="NU

2590 PRINT #3, " ЗНАЧЕНИЕ КРИТЕРИЯ РОМАНОВСКОГО =";

2595 PRINT #3, USING F2$;RK

2600 N=N1

2610 FOR I=1 TO N:PT(I+1)=P9(I+1)

2620 P(I)=P1(I):NEXT I

2630 IF IR9=1 THEN 3060

2640 INPUT "ТРЕБУЕТСЯ ЛИ РАСЧЕТ КРИТЕРИЯ МИЗЕСА(ДА- 1,НЕТ- 0)";IR3

2650 IF IR3=0 THEN 3060

2660 SW=0:I2=0:A1(0)=1E-38

2670 I2=I2+1

2680 IF I2>NO THEN 3040

2690 ON N3 GOSUB 2740,2760,2780,2780,2780,2780

2700 IF A1(I2)=A1(I2-1) THEN GOSUB 2800:GOTO 2670

2710 XW=A1(I2)

2720 ON N3 GOSUB 2820,2820,2890,2920,2950,3010

2730 GOSUB 2800:GOTO 2670

2740 FOR I=1 TO NO:A1(I)=(A(I)-ST(2))/ST(3):NEXT I

2750 RETURN

2760 FOR I=1 TO NO:A1(I)=(LOG(A(I)-XM)-YL)/SL:NEXT I

2770 RETURN

2780 FOR I=1 TO NO:A1(I)=A(I)-XM:NEXT I

2790 RETURN

2800 IF FW=>1 THEN FW=.999999

2805 IF FW<=0 THEN FW=1E-36

2808 SW=SW+(2*I2-1)*LOG(FW)+(2*NO-2*I2+1)*LOG(1-FW)

2810 RETURN

2820 C1=.049867347#:C2=.021141006#:C3=3.277626E-03

2830 C4=3.8004E-05:C5=4.8891E-05:C6=5.383E-06

2840 IF XW>0 THEN 2860

2850 XW=ABS(XW):GOSUB 2860:FW=1!-FW:GOTO 2880

2860 FW=1+C1*XW+C2*XW^2+C3*XW^3+C4*XW^4+C5*XW^5+C6*XW^6

2870 IF FW>230. THEN FW=1. ELSE FW=1!-FW^(-16!)/2.

2880 RETURN

2890 IF ((XW/SG)^2/2)>85 THEN FW=1!:GOTO 2910

2900 FW=1!-EXP(-((XW/SG)^2/2)):GOTO 2910

2910 RETURN

2920 IF PL*XW>85! THEN FW=1!:GOTO 2940

2930 FW=1!-EXP(-PL*XW):GOTO 2940

2940 RETURN

2950 IF EL*XW>80! THEN FW=1!:GOTO 3000

2960 VL=1!:VE=1!

2970 FOR M=1 TO KK

2980 VL=VL*EL*XW/M:VE=VE+VL:NEXT M

2990 FW=1!-EXP(-EL*XW)*VE

3000 RETURN

3010 IF XM^B/WL>85! THEN FW=1!:GOTO 3030

3020 FW=1!-EXP(-XW^B/WL):GOTO 3030

3030 RETURN

3040 W2=-NO-1/NO*SW

3050 PRINT #3, " ЗНАЧЕНИЕ КРИТЕРИЯ МИЗЕСА =";

3055 PRINT #3, USING F1$;W2

3060 RETURN

3070 INPUT"ТРЕБУЕТСЯ ПРОДОЛЖИТЬ РАСЧЕТЫ С ДРУГИМИ ДАННЫМИ";IR1

3080 IF IR1<>1 THEN 3095

3085 ERASE A,AA,UB,FR,ST,X,P,PT,P1,IN,P9,XX,A1,PM,PS,Z$,Z1$,Z2$

3095 COLOR 25,5,15:PRINT " РЕЗУЛЬТАТЫ РАСЧЕТА В ФАЙЛЕ RNDN.REZ"

3096 PRINT " ИСХОДНЫЕ ДАННЫЕ ДЛЯ ПОВТОРНОГО РАСЧЕТА В ФАЙЛЕ "IMF$

3097 BBB$=INKEY$

3098 IF LEN(BBB$)=0 THEN 3097

3099 RUN"RND.EXE"

3100 END

REM МОДУЛЬ ИССЛЕДОВАНИЯ ДИКРЕТНЫХ СЛУЧАЙНЫХ ВЕЛИЧИН

2 COLOR 7,7,15:CLS:LOCATE 10:PRINT:COLOR 0,7,15

3 PRINT TAB(27)"З А Д А Ч А R N D D":PRINT TAB(26)" ";

4 COLOR 15,0,15:PRINT"КАФЕДРА";:COLOR 23,5,15:PRINT" *БНТУ*";

5 COLOR 15,0,15:PRINT" О А П Д Д":PRINT:COLOR 1,14

6 PRINT TAB(21)"ИССЛЕДОВАНИЕ РАСПРЕДЕЛЕНИЯ ДИСКРЕТНОЙ";

7 PRINT TAB(80)" ";:PRINT TAB(27)"СЛУЧАЙНОЙ ВЕЛИЧИНЫ";

8 PRINT TAB(80)" ":DEFINT I-N

9 COLOR 7,10,15: PRINT:COLOR 7,0,7

20 DIM JA(100),NA(100)

25 COLOR 0,7:OPEN"O",#3,"RNDDR.REZ"

30 PRINT "ВВЕДЕНЫ ЛИ ИСХОДНЫЕ ДАННЫЕ"

35 COLOR 15,0

40 PRINT "ДА- 1, НЕТ- 0":INPUT IR1

50 IF IR1=0 THEN 200

55 INPUT"СПЕЦИФИКАЦИЯ ФАЙЛА С ИСХОДНЫМИ ДАННЫМИ ",IMF$

60 OPEN"I",#1,IMF$

65 INPUT #1,SI$

70 INPUT #1,NO

80 FOR I=1 TO NO:INPUT #1,JA(I),NA(I):NEXT I

90 CLOSE #1

100 CLS:PRINT"ПОРЯДКОВ. N ВЕЛИЧИНА ЧИСЛО ЗНАЧЕНИЙ"

110 FOR I=1 TO NO:PRINT I,JA(I),NA(I):NEXT I

115 COLOR 23,0

120 PRINT "ТРЕБУЕТСЯ ЛИ КОРРЕКТИРОВАТЬ ИСХОДНЫЕ ДАННЫЕ"

130 PRINT " ДА- 1,НЕТ- 0":INPUT IR0

135 COLOR 15,0

140 IF IR1=0 AND IR0=0 THEN 230

150 IF IR0=0 THEN 270

160 PRINT "ПОРЯДКОВЫЙ НОМЕР(СЧИТАЯ С ЕДИНИЦЫ) ЧИСЕЛ,ПОДЛЕЖАЩИХ"

170 PRINT "ИЗМЕНЕНИЮ":INPUT IS

175 PRINT "ЗАМЕНЯТЬ ЧИСЛА "JA(IS)," ",NA(IS):INPUT IRR:IF IRR=0 THEN 120

180 IF IS<1 OR IS>NO THEN PRINT "ВЫ ДОПУСТИЛИ ОШИБКУ":BEEP:GOTO 160

190 PRINT "НОВОЕ ЧИСЛО":INPUT JA(IS),NA(IS):IR1=0:GOTO 120

200 CLS: PRINT "ВВЕДИТЕ ИСХОДНЫЕ ДАННЫЕ":INPUT "НАИМЕНОВАНИЕ ДАННЫХ";SI$

205 INPUT "ЧИСЛО ГРУПП ЗНАЧЕНИЙ СЛУЧАЙНОЙ ВЕЛИЧИНЫ";NO

210 PRINT "ПОСЛЕДОВАТЕЛЬНО ЧЕРЕЗ ЗАПЯТУЮ ЗНАЧЕНИЕ СЛУЧАЙНОЙ ВЕЛИЧИНЫ"

215 PRINT "И ЧИСЛО НАБЛЮДЕНИЙ"

220 FOR I=1 TO NO:PRINT I"-Я ПАРА":INPUT JA(I),NA(I):NEXT I:GOTO 100

230 IF IR1=1 THEN 232

231 INPUT"ЗАДАЙТЕ СПЕЦИФИКАЦИЮ ФАЙЛА ДЛЯ ИСХОДНЫХ ДАННЫХ";IMF$

232 OPEN "O",#1,IMF$

235 WRITE #1,SI$

240 WRITE #1,NO

250 FOR I=1 TO NO:WRITE #1,JA(I),NA(I):NEXT I

260 CLOSE #1

270 DIM IUB(3),ST(3),P(100),P8(100),P0(100),BJ(100)

280 DIM P9(100),JR(100),PM(4),PS(4),Z$(4),Z1$(4)

281 NNS=0:SNN=0.:NNA=0:FOR I=1 TO NO:NNS=NNS+JA(I)*NA(I)

283 NNA=NNA+NA(I):SNN=SNN+JA(I)^2*NA(I):NEXT I

285 PRINT #3, TAB(10)"ИССЛЕДОВАНИЕ РАСПРЕДЕЛЕНИЯ ДИСКРЕТНОЙ СЛУЧАЙНОЙ ВЕЛИЧИНЫ"

286 PRINT #3, TAB(10)"("SI$")"

290 Z$(1)="БИНОМИАЛЬНОЕ":Z1$(1)="PB"

300 Z$(2)="ПУАССОНА":Z1$(2)="AP"

310 Z$(3)="ГЕОМЕТРИЧЕСКОЕ(ФАРРИ) (0...N)":Z1$(3)="PG"

320 Z$(4)="ГЕОМЕТРИЧЕСКОЕ(ФАРРИ) (1...N)":Z1$(4)="PG"

345 Z7$=" РАСПРЕДЕЛЕНИЕ НЕ ПОДХОДИТ"

346 Z8$=" РАСПРЕДЕЛЕНИЕ "

347 F$=".###^^^^":F1$="-.###^^^^"

350 PRINT #3,:PRINT #3, TAB(5)"ИСХОДНЫЕ ДАННЫЕ"

360 N4=INT(NO/8!):N5=NO-N4*8

370 FOR J=1 TO N4

380 FOR I=8*J-7 TO 8*J:PRINT #3, TAB(9*I-72*J+64) JA(I);:NEXT I

385 FOR I=8*J-7 TO 8*J:PRINT #3, TAB(9*I-72*J+64) NA(I);:NEXT I

390 PRINT #3,:NEXT J

400 FOR I=8*N4+1 TO NO:PRINT #3, TAB(9*I-72*N4-8) JA(I);:NEXT I

405 FOR I=8*N4+1 TO NO:PRINT #3, TAB(9*I-72*N4-8) NA(I);:NEXT I

406 PRINT #3,

410 ID=1

420 ID=2*ID

430 IF ID<=NO THEN 420

440 ID=INT((ID-1)/2!)

450 IF ID=0 THEN 530

460 FOR I1=1 TO NO-ID:J=I1

470 L=J+ID

480 IF JA(L)>=JA(J) THEN 510

490 IX=JA(J):IX1=NA(J):JA(J)=JA(L):NA(J)=NA(L):JA(L)=IX:NA(L)=IX1:J=J-ID

500 IF J>0 THEN 470

510 NEXT I1

520 GOTO 440

530 IUB(1)=JA(1):IUB(3)=JA(NO):N=IUB(3)-IUB(1)+1

535 JR(1)=NA(1)

540 II=0:FOR I=2 TO NO

542 IF JA(I-1)+1=JA(I) THEN JR(I+II)=NA(I):GOTO 560

545 JR(I+II)=0:II=II+1:JR(I+II)=NA(I)

560 NEXT I

570 FOR I=1 TO N:JA(I)=IUB(1)-1+I:NA(I)=JR(I):NEXT I

580 PRINT #3, " НАИМЕНЬШЕЕ ВЫБОРОЧНОЕ ЗНАЧЕНИЕ =";

585 PRINT #3, JA(1)

590 PRINT #3, " НАИБОЛЬШЕЕ ВЫБОРОЧНОЕ ЗНАЧЕНИЕ =";

592 PRINT #3, JA(NO)

630 GOTO 742

640 INPUT"ПРОДОЛЖИТЬ РАСЧЕТЫ С ЭТИМИ ДАННЫМИ(ДА- 1,НЕТ- 0)";N5

660 IF N5=0 THEN 3070 ELSE 980

742 ST(2)=NNS/NNA:ST(3)=SQR((SNN-NNA*ST(2)^2)/(NNA-1))

750 N9=1:V=ST(3)/ST(2)

760 PRINT #3, " МАТЕМАТИЧЕСКОЕ ОЖИДАНИЕ =";

765 PRINT #3, USING F$;ST(2)

770 PRINT #3, " СРЕДНЕКВАДРАТИЧЕСКОЕ ОТКЛОНЕНИЕ =";

775 PRINT #3, USING F$;ST(3)

780 PRINT #3, " КОЭФФИЦИЕНТ ВАРИАЦИИ =";

785 PRINT #3, USING F$;V: PRINT #3, " -------*****-------- "

880 PRINT #3,:PRINT #3, " ЗНАЧЕНИЯ ПЕРЕМЕННОЙ"

885 NF=N:FOR I= 1 TO N:BJ(I)=JA(I):NEXT I:GOSUB 890:GOTO 950

890 N4=INT(NF/8):N5=NF-N4*8:FOR J=1 TO N4

900 FOR I=8*J-7 TO 8*J:PRINT #3, TAB(9*I-72*J+64)USING F$;BJ(I);:NEXT I

910 PRINT #3,:NEXT J

920 FOR I=8*N4+1 TO NF:PRINT #3, TAB(9*I-72*N4-8)USING F$;BJ(I);:NEXT I

930 PRINT #3,:PRINT #3,:RETURN

950 PRINT #3, " ВЕКТОР ЭМПИРИЧЕСКИХ ЧАСТOCTEЙ"

960 FOR I=1 TO N:P9(I)=NA(I)/NNA:BJ(I)=P9(I):NEXT I:NF=N:GOSUB 890

980 PRINT #3, TAB(15)"** X **"

1160 PRINT " * ВВЕДИТЕ НОМЕР РАСПРЕДЕЛЕНИЯ"

1170 PRINT: PRINT " 1 - "Z$(1): PRINT " 2 - "Z$(2): PRINT " 3 - "Z$(3): PRINT " 4 - "Z$(4)

1240 INPUT N3

1250 ON N3 GOTO 1260,1500,1590,1680

1260 NW=NNA'INPUT" ВВЕДИТЕ ЧИСЛО ИСПЫТАНИЙ (РАЗМЕР ВЫБОРКИ)";NW

1265 PRINT #3,:PRINT #3, TAB(10)Z$(1),Z8$

1270 PB=ST(2)/NW:PRINT #3,:PRINT #3, TAB(5)Z1$(1)"=";:PRINT #3, USING F$;PB

1300 FOR I=1 TO N

1310 K=JA(I):GOSUB 2820:P(I)=PT:NEXT I

1320 NU=N-2

1340 PRINT #3,:PRINT #3, " ВЕКТОР ТЕОРEТИЧЕСКИХ ЧАСТОСТЕЙ":PRINT #3,

1350 FOR I=1 TO N:BJ(I)=P(I):NEXT I:NF=N:GOSUB 890

1360 INPUT"ТРЕБУЮТСЯ ЛИ ГРАФИКИ РАСПРЕДЕЛЕНИЯ(ДА- 1,НЕТ- 0)";IR2

1370 IF IR2=0 THEN 1480

1380 PRINT #3,:PRINT #3,:FOR I=2 TO 50:PRINT #3, TAB(I)"-";:NEXT I:PRINT #3,

1390 FOR I=1 TO N:P4=INT(P(I)*72):P5=INT(P9(I)*72)

1400 IF P4<P5 THEN 1430

1410 IF P4>P5 THEN 1440

1420 PRINT #3,"I";TAB(P4)"$":GOTO 1450

1430 PRINT #3,"I";TAB(P4)"+";TAB(P5)"#":GOTO 1450

1440 PRINT #3,"I";TAB(P5)"#";TAB(P4)"+"

1450 PRINT #3,"I":NEXT I:PRINT #3,

1460 PRINT #3,"+ -ТЕОРЕТ.РАСПРЕДЕЛЕНИЕ, # -ЭМПИРИЧЕСКОЕ РАСПРЕДЕЛЕНИЕ,";

1470 PRINT #3," $ -ПРИ СОВПАДЕНИИ"

1480 GOSUB 2250

1490 GOTO 640

1500 PRINT #3,:PRINT #3, TAB(10)Z8$,Z$(2)

1530 AP=ST(2):PRINT #3,:PRINT #3, TAB(5)Z1$(2)"=";USING F$;AP

1560 FOR I=1 TO N

1570 K=JA(I):GOSUB 2850:P(I)=PT:NEXT I

1580 GOTO 1320

1590 PRINT #3,:PRINT #3, TAB(10)Z8$,Z$(3)

1610 PG=1/ST(2):PRINT #3,:PRINT #3, TAB(5)Z1$(3)"=";USING F$;PG

1630 FOR I=1 TO N

1640 K=JA(I):GOSUB 2890:P(I)=PT:NEXT I

1660 GOTO 1320

1680 PRINT #3,:PRINT #3, TAB(10)Z8$,Z$(4)

1690 PG=1/ST(2):PRINT #3,:PRINT #3, TAB(5)Z1$(3)"=";USING F$;PG

1710 FOR I=1 TO N

1720 K=JA(I):GOSUB 2920:P(I)=PT:NEXT I

1740 GOTO 1320

2250 FOR I=1 TO N:P8(I)=P9(I):PO(I)=P(I):NEXT I

2260 N1=N:N11=NU:NN=N-N11+1:SM=P9(1)*NNA:SQ=0.

2270 I=2:L1=0

2280 IF N-L1<=NN THEN 2330

2290 IF SM>=5 THEN 2330

2300 SM=SM+P9(I)*NNA

2310 I=I+1:L1=L1+1

2320 GOTO 2280

2330 SM=P9(N)*NNA

2340 I=0:L2=0

2350 IF N-L1-L2<=NN GOTO 2380

2360 IF SM>=5 GOTO 2380

2370 L2=L2+1:I=I+1:SM=SM+P9(N-I)*NNA:GOTO 2350

2380 IF L1=0 THEN 2440

2390 FOR I=1 TO L1:P8(1)=P8(1)+P8(I+1)

2400 PO(1)=PO(1)+PO(I+1):NEXT I

2410 N=N-L1

2420 FOR I=2 TO N:P8(I)=P8(I+L1)

2430 PO(I)=PO(I+L1):NEXT I

2440 IF L2=0 THEN 2480

2445 N=N-L2

2450 FOR I=1 TO L2:P8(N)=P8(N)+P8(N+I)

2460 PO(N)=PO(N)+PO(N+I):NEXT I

2480 FOR I=1 TO N

2485 IF PO(I)<1E-36 THEN SQ=1.E+36:GOTO 2495

2490 SQ=SQ+((PO(I)-P8(I))^2)/PO(I)

2495 NEXT I

2500 SQ=SQ*NNA

2510 NU=N11-L2-L1

2520 RK=(SQ-NU)/SQR(2*NU)

2540 PRINT #3,:PRINT #3,:PRINT #3, " ВЕКТОР ТЕОРЕТИЧЕСКИХ ЧАСТОСТЕЙ C"

2550 PRINT #3, " ОБЬЕДИНЕНИЕМ ИНТЕРВАЛОВ НА КОНЦАХ"

2560 FOR I=1 TO N:BJ(I)=PO(I):NEXT I:NF=N:PRINT #3,:GOSUB 890

2570 PRINT #3,:PRINT #3,:PRINT #3, " ЗНАЧЕНИЕ ХИ-КВАДРАТ =";:

2575 PRINT #3, USING F$;SQ

2580 PRINT #3, " ЧИСЛО СТЕПЕНЕЙ СВОБОДЫ ="NU

2590 PRINT #3, " ЗНАЧЕНИЕ КРИТЕРИЯ РОМАНОВСКОГО =";

2595 PRINT #3, USING F1$;RK

2600 N=N1

2640 INPUT "ТРЕБУЕТСЯ ЛИ РАСЧЕТ КРИТЕРИЯ МИЗЕСА(ДА- 1,НЕТ- 0)";IR3

2650 IF IR3=0 THEN 3060

2660 SW=0.:I2=0:FT=0.:FO=0.

2670 I2=I2+1

2680 IF I2>N THEN 3040

2700 FT=FT+P(I2):IF FT<=0 THEN FT=1.E-36

2705 IF FT>=1. THEN FT=.999999

2800 FO=FO+P9(I2):IF FO<=0. THEN FO=1.E-36

2805 IF FO>=1. THEN FO=.999999

2806 SW=SW+(FO-FT)^2/(FT*(1-FT))

2810 GOTO 2670

2820 PI=1.:FOR J=1 TO K:PI=PI*(NW+1-J)/J:NEXT J:PT=PI*PB^K*(1.-PB)^(NW-K)

2830 RETURN

2850 FOR J=0 TO K:IF J=0 THEN PI=1. ELSE PI=PI*J

2885 NEXT J

2860 PT=AP^K/PI*EXP(-AP)

2880 RETURN

2890 PT=PG*(1.-PG)^K

2910 RETURN

2920 PT=PG/(1.-PG)*(1.-PG)^K

2940 RETURN

3040 'W2=-NO-1/NO*SW

3050 PRINT #3, " ЗНАЧЕНИЕ КРИТЕРИЯ МИЗЕСА =";

3055 PRINT #3, USING F$;SW

3060 RETURN

3070 PRINT"ПРОДОЛЖИТЬ РАСЧЕТЫ С ДРУГИМИ ДАННЫМИ(ДА- 1,НЕТ- 0"

3075 INPUT N5

3080 IF N5<>1 THEN 3095

3085 ERASE JA,NA,IUB,ST,P,P8,PO,BJ,P9,JR,PM,PS,S$,Z1$

3090 GOTO 19

3095 COLOR 25,5,15:PRINT " РЕЗУЛЬТАТЫ РАСЧЕТА В ФАЙЛЕ RNDD.REZ"

3096 PRINT " ИСХОДНЫЕ ДАННЫЕ ДЛЯ ПОВТОРНОГО РАСЧЕТА В ФАЙЛЕ "IMF$

3097 BBB$=INKEY$

3098 IF LEN(BBB$)=0 THEN 3097

3099 RUN"RND.EXE"

3100 END

Поиск по сайту: